構文 |
|
localtime time関数が返す形式の時刻 |
返り値 |
|
秒や分など9個の時刻情報 |
説明
- time関数が返す形式の時刻をローカルの時間に変換します。返す値は秒や分などを表す9個の要素を持つリストです。ただしスカラーコンテキストでは文字列で返します。
- 変数を省略して単にlocaltimeと書くとlocaltime(time)が実行され現在の時刻情報を返します。
- 9個のリストは先頭から順番に以下の値になります。
- 1. 秒
- 2. 分
- 3. 時
- 4. 日
- 5. 月(0~11) 1月の場合に0,2月の場合に1,……,12月の場合に11
- 6. 年(西暦から1900を引いた値) 2008年の場合に108
- 7. 曜日(0:日,1:月,……,6:土)
- 8. 年明けからの経過日数(1月1日の時に0)
- 9. サマータイムが有効の場合正の整数,無効の場合0,不明の場合負の整数
使用例
#!/usr/bin/perl
use strict;
use warnings;
my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday, $isdst)
= localtime(time);
$year += 1900;
$mon += 1;
print "$year年$mon月$mday日 $hour時$min分$sec秒\n";
#!/usr/bin/perl
use strict;
use warnings;
my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday, $isdst)
= localtime(time + 3600);
$year += 1900;
$mon += 1;
print "$year年$mon月$mday日 $hour時$min分$sec秒\n";
#!/usr/bin/perl
use strict;
use warnings;
my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday, $isdst)
= localtime;
$year += 1900;
$mon += 1;
printf
"%04d-%02d-%02d %02d:%02d:%02d\n",
$year, $mon, $mday, $hour, $min, $sec;
#!/usr/bin/perl
use strict;
use warnings;
my @now = localtime;
print "$now[2]時$now[1]分$now[0]秒\n";
#!/usr/bin/perl
use strict;
use warnings;
my $time_str = localtime(time);
print $time_str, "\n";
#!/usr/bin/perl
use strict;
use warnings;
use POSIX;
my $now = POSIX::strftime "%Y/%m/%d %H:%M:%S", localtime(time);
print $now, "\n";